# get quick furb for Tripple SDT scripts


# ----====[ show EGO banner :-) ]====----
echo "**" ANSI_1 "       --" ANSI_9 "===| " ANSI_11 "The Cabal's Furbing Tripple SDT Script v1.1.0" ANSI_9 "  |===" ANSI_1 "--*"
echo ANSI_1 "                --" ANSI_9 "===|  " ANSI_11 "Last edited March 31, 2003" ANSI_9 "  |===" ANSI_1 "--*"
echo ANSI_1 "                        --" ANSI_9 "===|  " ANSI_11 "By " ANSI_12 "Traitor" ANSI_9 "  |===" ANSI_1 "--**"
echo ANSI_10 "          This script is " ANSI_12 "not " ANSI_10 "freeware and may " ANSI_12 "not " ANSI_10 "be distributed*"
echo ANSI_10 "          or revised without written permission from the author.*"
echo "*" ANSI_13 "!! Please read the Notes and Warnings at the top of the script before using !!***"
echo "*" ANSI_12 "           !!! IF YOU ARE RUNNING SWATH, TURN OFF THE HELPER NOW !!!***" ANSI_10
echo ANSI_10 "**                         NOW TWX V2.X compatable!!" ANSI_7

# ====[ Getting data from Red 1, and creating new solosdtfile ]====
# User enters data manually here
echo "**Remember, the names are CASE SENSITIVE!!!**"
getinput $red1name  "Enter the name of the other red: " 0
getlength $red1name $red1namelen
echo "**Waiting for Red 1 to start script**"
:getdata
settextlinetrigger 10 :getinfored1 "transmission from"
pause
:getinfored1
killtrigger 10
cuttext CURRENTLINE $tempname 28 $red1namelen
if $tempname = $red1name
	settextlinetrigger 11 :setupshipvars "You are the furber"
	pause
	:setupshipvars
	killtrigger 11
	settextlinetrigger 13 :getship1num "ship1 ID"
	pause
	:getship1num
	killtrigger 13
	getword CURRENTLINE $ship1 3
	settextlinetrigger 14 :getship2num "ship2 ID"
	pause
	:getship2num
	killtrigger 14
	getword CURRENTLINE $ship2 3
	settextlinetrigger 15 :getship3num "ship3 ID"
	pause
	:getship3num
	killtrigger 15
	getword CURRENTLINE $ship3 3
	settextlinetrigger 15 :getred2name "Red2 name is:"
	pause
	:getred2name
	killtrigger 15
	gettext CURRENTLINE $red2name "is: " " :::"
	getlength $red2name $red2namelen
	echo "**ship1: " $ship1
	echo "**ship2: " $ship2
	echo "**ship3: " $ship3
	echo "**Red2 name: " $red2name
	goto :getotherinfo
else
	killalltriggers
	echo "*Name Mismatch, ignoring"
	echo "**tempname " $tempname
	echo "**red1name " $red1name
	goto :getdata
end

:getotherinfo
send "cz"
settextlinetrigger 20 :getmyshipnum "+"
pause
:getmyshipnum
killtrigger 20
getword CURRENTLINE $yourship 1
send "z"
waitfor "------"
settexttrigger 22 :gotallnums "Computer command"
settextlinetrigger 21 :getcoltsecs "Corp"
pause

:getcoltsecs
killtrigger 21
getword CURRENTLINE $temp 1
if $temp = $ship1
	getword CURRENTLINE $ship1sec 2
	settextlinetrigger 21 :getcoltsecs "Corp"
	pause
elseif $temp = $ship2
	getword CURRENTLINE $ship2sec 2
	settextlinetrigger 21 :getcoltsecs "Corp"
	pause
elseif $temp = $ship3
	getword CURRENTLINE $ship3sec 2
	settextlinetrigger 21 :getcoltsecs "Corp"
	pause
else
	settextlinetrigger 21 :getcoltsecs "Corp"
	pause
end

:gotallnums
killalltriggers
send "q"
send "=" & $red1name & "*"
send "I am ready**"
goto :waitforbust


:waitforbust
killalltriggers
settextlinetrigger 30 :checkifourred "transmission from"
pause
:checkifourred
killtrigger 30
cuttext CURRENTLINE $tempname1 28 $red1namelen
cuttext CURRENTLINE $tempname2 28 $red2namelen
if $tempname1 = $red1name
	settextlinetrigger 31 :getbustsector "I busted in ship"
	settexttrigger 32 :redoutturns "I am low on turns"
	pause
elseif $tempname2 = $red2name
	settextlinetrigger 31 :getbustsector "I busted in ship"
	settexttrigger 32 :redoutturns "I am low on turns"
	pause
else
	goto :waitforbust
end

:getbustsector
killtrigger 31
killtrigger 32
getword CURRENTLINE $shipbustnum 5
if $shipbustnum = $ship1
	setvar $bustsector $ship1sec
	gosub :getfurb
	goto :waitforbust
elseif $shipbustnum = $ship2
	setvar $bustsector $ship2sec
	gosub :getfurb
	goto :waitforbust
elseif $shipbustnum = $ship3
	setvar $bustsector $ship3sec
	gosub :getfurb
	goto :waitforbust
else
	echo ANSI_12 "**SHIP NUMBER MISMATCH!!  Halting script!!**" ANSI_7
	halt
end

:redoutturns
killalltriggers
echo ANSI_10 "**Red is low on turns.  Stopping script!**"
halt

:getfurb
killalltriggers
send "d"
waitfor "Sector"
settexttrigger 50 :notatSD "Command"
settexttrigger 51 :atsd "Stargate Alpha I"
pause
	:notatsd
	killalltriggers
	echo "**" ANSI_15 "YOU MUST BE AT STARDOCK!!" ANSI_7
	halt

	:atsd
	send "d"
	killalltriggers
	settextlinetrigger 52 :findsdsector "Command"
	pause
		:findsdsector
		killalltriggers
		gettext CURRENTLINE $sdsector "]:[" "] ("
		echo ANSI_15 "**This is the SD sector: " & $sdsector
	send "ps"
	settexttrigger 53 :yeslimpet "detected a Limpet"
	settexttrigger 54 :nolimpet "Where to?"
	pause
		:yeslimpet
		killalltriggers
		echo ANSI_12 "**LIMPET DETECTED!!! Halting script!!!**" ANSI_7
		send "y"
		halt

		:nolimpet
			send "sbnyhyp"
			setvar $furbname 0
			getrnd $furbrand 1 999999
			setvar $furbname "furb" & $furbrand
			echo "**" ANSI_15 "This will be the Furb's name: " $furbname
			send $furbname "*n*qq"
			waitfor "blast off from"
			send "x*"
			waitfor "------"
			settextlinetrigger 55 :findfurbshipnum $furbname
			pause
				:findfurbshipnum
				killalltriggers
				getword CURRENTLINE $furbnumb 1
				echo ANSI_15 CURRENTLINE
				echo "**" ANSI_15 "This is the furb ship number: " $furbnumb
			waitfor "Choose which ship"
			send $furbnumb "*qpsspa33*yqqq"
			send "x*" $yourship "*q"
			send "wn" $furbnumb "*"
			waitfor "sector you move"
			send "m" $bustsector "*y"
			gosub :twarpcheck
			send "w"
			send "pt**"
			send "m" $sdsector "*y"
			gosub :twarpcheck
			return
			
# ====[ Furb checks for safe t-warp here ]====
:twarpcheck
settexttrigger 660 :safetwarp "Locked."
settexttrigger 661 :unsafetwarp "No locating beam found for sector"
pause
	:safetwarp
	killalltriggers
	send "y"
	return

	:unsafetwarp
	killalltriggers
	send "n"
	echo "**" ANSI_12 "NOT SAFE TO TWARP!!! STOPPING SCRIPT!!!**" ANSI_7
	halt